[vdr] Re: Creating audio WAV from 00?.vdr

[Dave Chapman <dave@dchapman.com>]

Andreas Tille wrote:
> > There are other options for sound editing e.g quickedit
> > (see http://www.penguin.cz/~slezak/quickedit-0.3.2.tar.gz)
> I think I could do it using audacity which I'm comfortable with.
You may be interested in a small AWK script I wrote.

You load a large (e.g. 1 hour) WAV file into Audacity, then create a new 
"Label track", and then add label marks where you want the track splits 
to be on your CD.

You then save this label track as a text file - e.g. "labels.txt"

Save the script included as the end of this email as "aud2cue.k", and 
then do:

awk -vW="wavfile.wav" -f aud2cue.k labels.txt > cuefile.cue

This will then give you a cuefile you can use to burn a CD using cdrdao.

The advantage of this is that the WAV file is burnt as a continuous 
audio stream on the CD - if you split it into separate WAV files, then 
(unless you knew what you were doing), you could get short gaps between 
the tracks

Regards,

Dave.

---- cut here - save as "aud2cue.k" -----
BEGIN {
  FS="\t"
  WAV=W
}

{ n=split($1,a,".")
  x=a[1]
  if (n==1) {
    f=0
  } else {
    f=75*("0."a[2])
    gsub(/\..*/,"",f)
  }
  tracks++
  frames[tracks]=f+(x*75)
}

END {
  print "CD_DA"
  print ""
  for (i=1;i<=tracks;i++) {
    print "TRACK AUDIO"
    printf("FILE \"%s\" ",WAV)
    print_frames(frames[i]);
    if (i < tracks) {
      printf(" ")
      print_frames(frames[i+1]-frames[i])
    }
    printf("\n");
  }
}

function print_frames(frames, m,s,f) {
  f=frames%75
  frames=(frames-f)/75
  s=frames%60
  m=(frames-s)/60

  printf("%02d:%02d:%02d",m,s,f)
}
--- end cut ---


--
Info:
To unsubscribe send a mail to ecartis@linuxtv.org with "unsubscribe vdr" as subject.